tutorial pengembangan web terbaru
 

ADO Speed ​​Up Dengan GetString ()


Gunakan GetString() metode untuk mempercepat script ASP Anda (bukan menggunakan beberapa Response.Write ini).


Beberapa Response.Write ini

Contoh berikut menunjukkan salah satu cara bagaimana untuk menampilkan query database dalam tabel HTML:

<html>
<body>

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>

<table border="1" width="100%">
<%do until rs.EOF%>
  <tr>
    <td><%Response.Write(rs.fields("Companyname"))%></td>
    <td><%Response.Write(rs.fields("Contactname"))%></td>
  </tr>
<%rs.MoveNext
loop%>
</table>

<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>

</body>
</html>

Untuk pertanyaan besar, ini dapat memperlambat waktu proses skrip, karena banyak perintah Response.Write harus diproses oleh server.

Solusinya adalah dengan telah seluruh string dibuat, dari <table> untuk </ table>, dan kemudian output - menggunakan Response.Write hanya sekali.


The GetString() Method

The GetString() metode memungkinkan Anda untuk menampilkan string dengan hanya satu Response.Write. Hal ini juga menghilangkan do ... lingkaran kode dan tes kondisional yang memeriksa apakah recordset adalah di EOF.

Sintaksis

str = rs.GetString(format,rows,coldel,rowdel,nullexpr)

Untuk membuat sebuah tabel HTML dengan data dari recordset, kita hanya perlu menggunakan tiga parameter di atas (all parameters are optional) :

  • coldel - HTML untuk digunakan sebagai kolom-pemisah
  • rowdel - HTML untuk digunakan sebagai baris-pemisah
  • nullexpr - HTML untuk digunakan jika kolom adalah NULL

Note: The GetString() metode adalah ADO 2.0 fitur. Anda dapat men-download ADO 2.0 di http://www.microsoft.com/data/download.htm .

Pada contoh berikut kita akan menggunakan GetString() metode untuk memegang recordset sebagai string:

Contoh

<html>
<body>

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn

str=rs.GetString(,,"</td><td>","</td></tr><tr><td>","&nbsp;")
%>

<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>

<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Tampilkan contoh »

Variabel str di atas mengandung string dari semua kolom dan baris yang dikembalikan oleh pernyataan SQL SELECT. Antara setiap kolom HTML </td><td> akan muncul, dan antara setiap baris, HTML </td></tr><tr><td> akan muncul. Ini akan menghasilkan HTML yang tepat kita perlu dengan hanya satu Response.Write.